dnl Process this file with autoconf to produce a configure script.
dnl
dnl This file configure.in is part of the t1lib-package (V. 0.9.1).
dnl 
dnl Author:         Rainer Menzner (Rainer.Menzner@neuroinformatik.ruhr-uni-bochum.de)
dnl Date:           06/25/1997
dnl Last Modified:  1999-05-20
dnl 

AC_REVISION([configure.in 1.00])
AC_INIT(lib/t1lib/t1base.c)		
AC_CONFIG_HEADER(lib/t1lib/sysconf.h:lib/t1lib/sysconf.h.in)
AC_CONFIG_AUX_DIR(ac-tools)

dnl The following variables determine the name and the soname of the
dnl shared library!
T1LIB_VERSION="0"
T1LIB_REVISION="9"
T1LIB_PATCHLEVEL="1"
T1LIB_IDENTIFIER="0.9.1"


dnl We set CFLAGS in order to have complete control over compiler 
dnl switches during development
dnl CFLAGS="$CFLAGS -g -Wall"


dnl  -----------------------------------------------------------
dnl         Do not change anthing below this line!
dnl  -----------------------------------------------------------


dnl I really do not like the versioning system of libtool, so we fool
dnl it by the following trick:
T1LIB_LTCURRENT=`expr $T1LIB_VERSION + $T1LIB_REVISION`

dnl We use this file by Andreas Zeller to check for libXaw
builtin(include, ac-tools/ice_find_athena.m4)
builtin(include, ac-tools/aclocal.m4)

# We want these before the checks, so the checks can modify their values.
test -z "$LDLIBS" && LDLIBS=-lm   AC_SUBST(LDLIBS)
test -z "$PROGEXT" && PROGEXT=""  AC_SUBST(PROGEXT)
test -z "$CFLAGS"                 AC_SUBST(CFLAGS)
test -z "$LDFLAGS"                AC_SUBST(LDFLAGS)

T1LIB_DATA_DIR="${datadir}/t1lib-${T1LIB_VERSION}.${T1LIB_REVISION}"

dnl The following variables should be used

AC_SUBST(T1LIB_VERSION)
AC_SUBST(T1LIB_REVISION)
AC_SUBST(T1LIB_PATCHLEVEL)
AC_SUBST(T1LIB_LTCURRENT)
AC_SUBST(T1LIB_DATA_DIR)
AC_SUBST(T1LIB_IDENTIFIER)
AC_SUBST(MAIN_TARGET)
AC_SUBST(MAIN_HEADER)
AC_SUBST(OPTIONS)
AC_SUBST(no_x)    
AC_SUBST(CC)
AC_SUBST(T1_AA_TYPE16)
AC_SUBST(T1_AA_TYPE32)
AC_SUBST(T1_AA_TYPE64)
AC_SUBST(XSUBDIRS)
AC_SUBST(T1LIBX_OBJS)
AC_SUBST(T1LIBX_SRCS)
AC_SUBST(T1LIBX_HEADERS)
AC_SUBST(XOBJS)


dnl **** Check for some programs and libraries ****

AC_PROG_MAKE_SET
AC_PROG_CC
AC_PROG_CPP
AC_PATH_XTRA
ICE_FIND_ATHENA
AM_PROG_LIBTOOL
AC_PROG_INSTALL

dnl **** Check for some compiler/system characteristics

AC_C_CHAR_UNSIGNED
AC_CHECK_SIZEOF(char,0)
AC_CHECK_SIZEOF(short,0)
AC_CHECK_SIZEOF(int,0)
AC_CHECK_SIZEOF(long,0)
AC_CHECK_SIZEOF(long long,0)
AC_CHECK_SIZEOF(float,0)
AC_CHECK_SIZEOF(double,0)
AC_CHECK_SIZEOF(long double,0)
AC_CHECK_SIZEOF(void *,0)

dnl **** Check for gcc strength-reduce bug ****

if test "x${GCC}" = "xyes"
then
dnl We don'use
  CFLAGS="$CFLAGS"
  AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
                  AC_TRY_RUN([
int main(void) {
  static int Array[[3]];
  unsigned int B = 3;
  int i;
  for(i=0; i<B; i++) Array[[i]] = i - 3;
  exit( Array[[1]] != -2 );
}],
    ac_cv_c_gcc_strength_bug="no",
    ac_cv_c_gcc_strength_bug="yes",
    ac_cv_c_gcc_strength_bug="yes") )
  if test "$ac_cv_c_gcc_strength_bug" = "yes"
  then
    CFLAGS="$CFLAGS -fno-strength-reduce"
  fi
fi

dnl **** Check for underscore on external symbols ****

AC_CACHE_CHECK("whether external symbols need an underscore prefix",
               ac_cv_c_extern_prefix,
[saved_libs=$LIBS
LIBS="conftest_asm.s $LIBS"
cat > conftest_asm.s <<EOF
	.globl _ac_test
_ac_test:
	.long 0
EOF
AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
            ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
LIBS=$saved_libs])
if test "$ac_cv_c_extern_prefix" = "yes"
then
  AC_DEFINE(NEED_UNDERSCORE_PREFIX)
fi

dnl **** Check which ANSI integer type is 16 bit 

AC_CACHE_CHECK( "which ANSI integer type is 16 bit", ac_16bit_type,
		AC_TRY_RUN([
int main(void) {
  if (sizeof(short)==2)
    return(0);
  else if (sizeof(int)==2)
    return(1);
  else
    return(2);
}], ac_16bit_type="short", ac_16bit_type="int", ac_16bit_type=))
if test "$ac_16bit_type" = "short"
then
  T1_AA_TYPE16="short"
else
  T1_AA_TYPE16="int"
fi


dnl **** Check which ANSI integer type is 32 bit 

AC_CACHE_CHECK( "which ANSI integer type is 32 bit", ac_32bit_type,
		AC_TRY_RUN([
int main(void) {
  if (sizeof(int)==4)
    return(0);
  else if (sizeof(long)==4)
    return(1);
  else
    return(2);
}], ac_32bit_type="int", ac_32bit_type="long", ac_32bit_type=))
if test "$ac_32bit_type" = "int"
then
  T1_AA_TYPE32="int"
else
  T1_AA_TYPE32="long"
fi


dnl **** Check which ANSI integer type is 64 bit 

AC_CACHE_CHECK( "which ANSI integer type is 64 bit", ac_64bit_type,
		AC_TRY_RUN([
int main(void) {
  if (sizeof(long)==8)
    return(0);
  else
    return(1);
}], ac_64bit_type="long", ac_64bit_type="<none>"))
if test "$ac_64bit_type" = "long"
then
  T1_AA_TYPE64="long"
else
  T1_AA_TYPE64=
fi


CFLAGS="${CFLAGS} -DT1LIB_IDENT=\"\\\"${T1LIB_IDENTIFIER}\\\"\" -DGLOBAL_CONFIG_DIR=\"\\\"${T1LIB_DATA_DIR}\\\"\""

dnl **** Check for functions and header files ****

AC_HEADER_STAT()
AC_C_CONST()
AC_TYPE_SIZE_T()

dnl **** with or without X11 ****

if test "$no_x" = "yes"	
then
MAIN_TARGET="libt1.la"
MAIN_HEADER="t1lib.h"
XSUBDIRS=""
T1LIBX_OBJS=""
T1LIBX_SRCS=""
T1LIBX_HEADERS=""
XOBJS=""
else
MAIN_TARGET="libt1.la libt1x.la"
MAIN_HEADER="t1lib.h t1libx.h"
XSUBDIRS="xglyph"
T1LIBX_OBJS="t1lib/t1x11.lo"
T1LIBX_SRCS="t1lib/t1x11.c"
T1LIBX_HEADERS="t1lib/t1x11.h t1lib/t1libx.h"
XOBJS="t1x11.lo"
fi


dnl **** Generate output files ****

dnl Some new versions of autonconf do not seem to set 
dnl -DX_DISPLAY_MISSING -> we do it by hand:
if test "$no_x" = "yes"	
then
CFLAGS="${CFLAGS} -DT1LIB_NO_X11_SUPPORT"
MAKEFILES="Makefile \
           lib/Makefile \
	   lib/type1/Makefile \
	   lib/t1lib/Makefile \
	   type1afm/Makefile \
	   examples/Makefile \
	   doc/Makefile"
else
MAKEFILES="Makefile \
           lib/Makefile \
	   lib/type1/Makefile \
	   lib/t1lib/Makefile \
	   xglyph/Makefile \
	   type1afm/Makefile \
	   examples/Makefile \
	   doc/Makefile"
fi


AC_OUTPUT([
$MAKEFILES
])



echo
echo "Configure finished!" 
echo "        Do:  'make'               to compile the t1lib-package."
echo "        Do:  'make without_doc'   to compile if you do not have LaTeX."
echo "        Do:  'make install'       to install the t1lib-package."
echo ""
dnl echo "        Do:  'make t1python-all' to compile the t1python-package."
dnl echo ""

dnl Local Variables:
dnl comment-start: "dnl "
dnl comment-end: ""
dnl comment-start-skip: "\\bdnl\\b\\s *"
dnl compile-command: "autoconf"
dnl End: